summaryrefslogtreecommitdiffstats
path: root/tp2-files/Calculatrice-final.jj
blob: 9a03f3935a61774ca847c31040f9be28d0c44459 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
// Options pour JavaCC
options { LOOKAHEAD=1; FORCE_LA_CHECK=true; }

// Fonction principale
PARSER_BEGIN(Calculatrice)
public class Calculatrice
{
    public static void main(String args[]) throws ParseException 
    {
        Calculatrice parser = new Calculatrice(System.in);
        parser.boucle();
    }
}
PARSER_END(Calculatrice)

// Caractères à ignorer (espaces)
SKIP: { " " | "\r" | "\t" }

// Définitions pour le lexeur
TOKEN:
{
    < NUMBER: (<DIGIT>)+ ("." (<DIGIT>)*)? >  // Un nombre en décimal
|   < DIGIT: ["0"-"9"] >  // Un chiffre
|   < EOL: "\n" >  // Fin de ligne
}

// Boucle principale: lire des expressions sur une ligne jusqu'à fin de fichier
//     boucle → (expression <EOL>)* <EOF>
// (<EOL> est défini ci-dessus, <EOF> est reconnu automatiquement)
void boucle():
{ double a; }
{
    (
      a=expression() <EOL> { System.out.println(a); }
    )*
    <EOF>
}

// Expression (axiome de la grammaire de la calculatrice)
//     expression → terme ( "+" terme | "-" terme )*
double expression():
{ double a,b; }
{
    a=terme()
    (
      "+" b=terme() { a += b; }
    | "-" b=terme() { a -= b; }
    )* { return a; }
}

// Terme d'une somme ou différence
//     terme → unaire ( "*" unaire | "/" unaire )*
double terme():
{ double a,b; }
{
    a=unaire()
    (
      "*" b=unaire() { a *= b; }
    | "/" b=unaire() { a /= b; }
    )* { return a; }
}

// Gestion du "+" et "−" unaires
//     unaire → puissance | "+" puissance | "-" puissance
double unaire():
{ double a; }
{
    a=puissance() { return a; }
|   "+" a=puissance() { return a; }
|   "-" a=puissance() { return -a; }
}

// Opération puissance (associative à droite)
//     puissance → element ( "^" unaire )?
double puissance():
{ double a,b; }
{
    a=element()
    (
      "^" b=unaire() { a = Math.pow(a,b); }
    )? { return a; }
}

// Élément d'un calcul (nombre ou expression parenthésée)
double element():
{ Token t; double a; }
{
    t=<NUMBER> { return Double.parseDouble(t.toString()); }
|   "(" a=expression() ")" { return a; }
}